[]
[Excel Macro] PDF olarak kaydedip E-mail olarak göndermek
selamlar,
elimde bir excel form var, normalde doldurulduktan sonra yazdırılıp imzaya çıkarılıyor. bir değişiklik yapıp macro atanmış bir düğme yardımıyla bu formu önce PDF olarak kaydettirip, ardından da belirli bir email metni ile formda kişilerin doldurduğu email adreslerine otomatik olarak göndersin istiyorum.
sadece PDF yapıp email atma olayıyla ilgili bir sürü macro buldum internette, ama TO ve CC kısımlarına gelecek adresleri formun içindeki belli yerlerden çekilmesini sağlayabilecek kısmı yapmamış sanırsam kimse (ya da ben bulamadım) :\
bu kısmın da dahil olduğu bir macro koduna denk gelirseniz, ya da nasıl yazılabileceğini biliyorsanız süper olur!
not: excel 2010 / outlook 2010
teşekkürler, mutlu günler!
elimde bir excel form var, normalde doldurulduktan sonra yazdırılıp imzaya çıkarılıyor. bir değişiklik yapıp macro atanmış bir düğme yardımıyla bu formu önce PDF olarak kaydettirip, ardından da belirli bir email metni ile formda kişilerin doldurduğu email adreslerine otomatik olarak göndersin istiyorum.
sadece PDF yapıp email atma olayıyla ilgili bir sürü macro buldum internette, ama TO ve CC kısımlarına gelecek adresleri formun içindeki belli yerlerden çekilmesini sağlayabilecek kısmı yapmamış sanırsam kimse (ya da ben bulamadım) :\
bu kısmın da dahil olduğu bir macro koduna denk gelirseniz, ya da nasıl yazılabileceğini biliyorsanız süper olur!
not: excel 2010 / outlook 2010
teşekkürler, mutlu günler!
Senin bulduklarında da vardır o kısım mutlaka.
TO ve CC olmadan mail mi olur :)
Bulduğun kodu gönder, düzenleyip yardımcı olayım.
TO ve CC olmadan mail mi olur :)
Bulduğun kodu gönder, düzenleyip yardımcı olayım.
- cakabo
(13.08.15 10:42:20)
var cakabo var, ama TO ve CC kısımlarına macro içinde adres atamışlar, dinamik değil gördüklerim.
bir de bu kadar gördüğüm örneklerin birinde 1 eksik, diğerinde 5 eksik var, hepsini birleştirsem ancak istediğim bişeyi bile elde edemiyorum :D
istediğime yakın bişey bulursam buraya da koyucam, ya da sana mesajla da atabilirim olmadı, çok sağol :)
bir de bu kadar gördüğüm örneklerin birinde 1 eksik, diğerinde 5 eksik var, hepsini birleştirsem ancak istediğim bişeyi bile elde edemiyorum :D
istediğime yakın bişey bulursam buraya da koyucam, ya da sana mesajla da atabilirim olmadı, çok sağol :)
- loveinaflipbook
(13.08.15 10:49:39)
PDF olarak kaydetmiyor da ayri bir workbook olarak kaydediyor su[1] ornek. Onu degistirirsiniz kolayca. E-posta gonderilecek adresleri ise dinamik olarak olusturuyor. Uzerinde biraz oynama yapmak gerekecektir ama istediginiz islemlerin buyuk cogunlugunu yapiyor su haliyle bile.
[1] chandoo.org
[1] chandoo.org
- dahicocuk (13.08.15 11:01:22)
çözdüm gençler! hücreden veri çağırmayı öğrenince gerisi geldi :) isteyenler için aşağıda üzerinde değişiklik yapmadan önceki kodu paylaşıyorum. teşekkür ederim hepinize!
Sub AttachActiveSheetPDF()
Dim IsCreated As Boolean
Dim i As Long
Dim PdfFile As String, Title As String
Dim OutlApp As Object
' Not sure for what the Title is
Title = Range("A1")
' Define PDF filename
PdfFile = ActiveWorkbook.FullName
i = InStrRev(PdfFile, ".")
If i > 1 Then PdfFile = Left(PdfFile, i - 1)
PdfFile = PdfFile & "_" & ActiveSheet.Name & ".pdf"
' Export activesheet as PDF
With ActiveSheet
.ExportAsFixedFormat Type:=xlTypePDF, Filename:=PdfFile, Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False
End With
' Use already open Outlook if possible
On Error Resume Next
Set OutlApp = GetObject(, "Outlook.Application")
If Err Then
Set OutlApp = CreateObject("Outlook.Application")
IsCreated = True
End If
OutlApp.Visible = True
On Error GoTo 0
' Prepare e-mail with PDF attachment
With OutlApp.CreateItem(0)
' Prepare e-mail
.Subject = Title
.To = Range("A5") ' <-- Put email of the recipient here
.CC = Range("B5") ' <-- Put email of 'copy to' recipient here
.Body = "Hi," & vbLf & vbLf _
& "The report is attached in PDF format." & vbLf & vbLf _
& "Regards," & vbLf _
& Application.UserName & vbLf & vbLf
.Attachments.Add PdfFile
' Try to send
On Error Resume Next
.Send
Application.Visible = True
If Err Then
MsgBox "E-mail was not sent", vbExclamation
Else
MsgBox "E-mail successfully sent", vbInformation
End If
On Error GoTo 0
End With
' Delete PDF file
Kill PdfFile
' Quit Outlook if it was created by this code
If IsCreated Then OutlApp.Quit
' Release the memory of object variable
Set OutlApp = Nothing
End Sub
Sub AttachActiveSheetPDF()
Dim IsCreated As Boolean
Dim i As Long
Dim PdfFile As String, Title As String
Dim OutlApp As Object
' Not sure for what the Title is
Title = Range("A1")
' Define PDF filename
PdfFile = ActiveWorkbook.FullName
i = InStrRev(PdfFile, ".")
If i > 1 Then PdfFile = Left(PdfFile, i - 1)
PdfFile = PdfFile & "_" & ActiveSheet.Name & ".pdf"
' Export activesheet as PDF
With ActiveSheet
.ExportAsFixedFormat Type:=xlTypePDF, Filename:=PdfFile, Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False
End With
' Use already open Outlook if possible
On Error Resume Next
Set OutlApp = GetObject(, "Outlook.Application")
If Err Then
Set OutlApp = CreateObject("Outlook.Application")
IsCreated = True
End If
OutlApp.Visible = True
On Error GoTo 0
' Prepare e-mail with PDF attachment
With OutlApp.CreateItem(0)
' Prepare e-mail
.Subject = Title
.To = Range("A5") ' <-- Put email of the recipient here
.CC = Range("B5") ' <-- Put email of 'copy to' recipient here
.Body = "Hi," & vbLf & vbLf _
& "The report is attached in PDF format." & vbLf & vbLf _
& "Regards," & vbLf _
& Application.UserName & vbLf & vbLf
.Attachments.Add PdfFile
' Try to send
On Error Resume Next
.Send
Application.Visible = True
If Err Then
MsgBox "E-mail was not sent", vbExclamation
Else
MsgBox "E-mail successfully sent", vbInformation
End If
On Error GoTo 0
End With
' Delete PDF file
Kill PdfFile
' Quit Outlook if it was created by this code
If IsCreated Then OutlApp.Quit
' Release the memory of object variable
Set OutlApp = Nothing
End Sub
- loveinaflipbook (13.08.15 13:06:27)
1
